force tooltip display

Just starting out? Need help? Post your questions and find answers here.
pf shadoko
Posts: 74
Joined: Thu May 26, 2016 11:09 am

force tooltip display

Post by pf shadoko »

Hello,

Depending on the value entered in a stringgadget, I want to display or not a tooltip
Problem: the tooltip appears only if I move the mouse on the gadget
Someone knows how to force tooltip display ?
User avatar
Peter
Posts: 1086
Joined: Mon Feb 24, 2014 10:17 pm
Location: 127.0.0.1:9080
Contact:

Re: force tooltip display

Post by Peter »

pf shadoko wrote:Someone knows how to force tooltip display ?
Here is an example how to Show & Hide a Tooltip on a Gadget:

Code: Select all

EnableExplicit

#Window = 0
#StringGadget = 0

Procedure ShowTooltip(Gadget, TooltipText.s, Position.s = "right")
  ; Position: you can use "above", "below", "right" or "left"  
  !  dijit.showTooltip(v_tooltiptext, dijit.byId(spider_GadgetID(v_gadget).gadget.id).domNode, [v_position]);
EndProcedure

Procedure HideTooltip(Gadget)
  !  dijit.hideTooltip(dijit.byId(spider_GadgetID(v_gadget).gadget.id).domNode);
EndProcedure

Procedure StringGadgetEvent()
  
  Select EventType()
    Case #PB_EventType_Focus, #PB_EventType_Change
      ShowTooltip(#StringGadget, "Your Text: '" + GetGadgetText(#StringGadget) + "'", "below")
    Case #PB_EventType_LostFocus
      HideTooltip(#StringGadget)
  EndSelect
  
EndProcedure

OpenWindow(#Window, 0, 0, 322, 205, "Show & Hide Tooltip", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)

StringGadget(#StringGadget, 8,  10, 306, 20, "Normal StringGadget...")

BindGadgetEvent(#StringGadget, @StringGadgetEvent())
Greetings ... Peter
pf shadoko
Posts: 74
Joined: Thu May 26, 2016 11:09 am

Re: force tooltip display

Post by pf shadoko »

perfect

Thank you very much peter
Post Reply